A formal grammar for CIF in extended Backus-Naur form.

This is a terse summary of the CIF grammar in an extended Backus-Naur
form. An expanded listing with full description is found in the CIF
syntax document. The full syntax document should be read for information
about specifications that cannot be expressed in a context-free
Backus-Naur form.

The grammar is presented twice. Version (i) is a plain-text version of the
tabular form displayed in the CIF syntax document, with indication of case
sensitivity and laid out for convenient reading in a fixed-width typeface.
Version (ii) is more compact and omits headings and information about case
sensitivity. Productions use the symbol ::= to separate left and right sides.
This version can be directly machine-parsed.

================================================================================
(i) Tabular form
================================================================================

Basic Structure of a CIF
--------------------------------------------------------------------------------
syntactic unit      syntax                                       case sensitive?
--------------------------------------------------------------------------------
<CIF>               <Comments>? <WhiteSpace>? { <DataBlock> {               yes
                      <WhiteSpace> <DataBlock> }* {
                      <WhiteSpace> }? }?
<DataBlock>         <DataBlockHeading> {<WhiteSpace> {
                      <DataItems> | <SaveFrame>} }*                         yes
<DataBlockHeading>  <DATA_> { <NonBlankChar> }+                              no
<SaveFrame>         <SaveFrameHeading> { <WhiteSpace> <DataItems> }+        yes
                      <WhiteSpace> <SAVE_>
<SaveFrameHeading>  <SAVE_> { <NonBlankChar> }+                              no
<DataItems>         <Tag> <WhiteSpace> <Value> |                            yes
                      <LoopHeader> <LoopBody>
<LoopHeader>        <LOOP_> {<WhiteSpace> <Tag>}+                            no
<LoopBody>          <Value> { <WhiteSpace> <Value> }*                       yes

Reserved Words
--------------------------------------------------------------------------------
syntactic unit      syntax                                       case sensitive?
--------------------------------------------------------------------------------
<DATA_>             {'D' | 'd'} {'A' | 'a'} {'T' | 't'} {'A' | 'a'} '_'      no
<LOOP_>             {'L' | 'l'} {'O' | 'o'} {'O' | 'o'} {'P' | 'p'} '_'      no
<GLOBAL_>           {'G' | 'g'} {'L' | 'l'} {'O' | 'o'} {'B' | 'b'}          no
                      {'A' | 'a'} {'L' | 'l'} '_'
<SAVE_>             {'S' | 's'} {'A' | 'a'} {'V' | 'v'} {'E' | 'e'} '_'      no
<STOP_>             {'S' | 's'} {'T' | 't'} {'O' | 'o'} {'P' | 'p'} '_'      no

Tags and Values
--------------------------------------------------------------------------------
syntactic unit      syntax                                       case sensitive?
--------------------------------------------------------------------------------
<Tag>               '_'{ <NonBlankChar>}+                                    no
<Value>             { '.' | '?' | <Numeric> | <CharString> |  <TextField> } yes

Numeric Values
--------------------------------------------------------------------------------
syntactic unit      syntax                                       case sensitive?
--------------------------------------------------------------------------------
<Numeric>           { <Number> | <Number> '(' <UnsignedInteger> ')' }        no
<Number>            {<Integer> | <Float> }                                   no
<Integer>           { '+' | '-' }? <UnsignedInteger>                         no
<Float>             { <Integer><Exponent> |                                  no
                      { {'+'|'-'} ? { {<Digit>} * '.' <UnsignedInteger> } |
                      { <Digit>} + '.' } } {<Exponent>} ? } }
<Exponent>          { {'e' | 'E' } | {'e' | 'E' } { '+' | '- ' } }           no
                      <UnsignedInteger>
<UnsignedInteger>   { <Digit> }+                                             no
<Digit>             { '0' | '1' | '2' | '3' | '4' | '5' | '6' | '7' |        no
                      '8' | '9' }

Character Strings and Text Fields
--------------------------------------------------------------------------------
syntactic unit      syntax                                       case sensitive?
--------------------------------------------------------------------------------
<CharString>        <UnquotedString> | <SingleQuotedString> |               yes
                      <DoubleQuotedString>
<eol><UnquotedString>  <eol><OrdinaryChar> {<NonBlankChar>}*                yes
<noteol><UnquotedString>
                    <noteol>{<OrdinaryChar>|';'} {<NonBlankChar>}*          yes
<SingleQuotedString><WhiteSpace>                                            yes
                    <single_quote>{<AnyPrintChar>}*
                       <single_quote> <WhiteSpace>
<DoubleQuotedString><WhiteSpace>                                            yes
                    <double_quote> {<AnyPrintChar>}*
                       <double_quote> <WhiteSpace>
<TextField>         { <SemiColonTextField> }                                yes
<eol><SemiColonTextField>
                    <eol>';' { {<AnyPrintChar>}* <eol>                      yes
                      {{<TextLeadChar> {<AnyPrintChar>}*}? <eol>}* } ';'

WhiteSpace and Comments
--------------------------------------------------------------------------------
syntactic unit      syntax                                       case sensitive?
--------------------------------------------------------------------------------
<WhiteSpace>        { <SP> | <HT> | <eol> | <TokenizedComments>}+           yes
<Comments>          { '#' {<AnyPrintChar>}* <eol>}+                         yes
<TokenizedComments> { <SP> | <HT> | <eol> |}+ <Comments>                    yes

Character Sets
--------------------------------------------------------------------------------
syntactic unit      syntax                                       case sensitive?
--------------------------------------------------------------------------------
<OrdinaryChar>      { '!' | '%' | '&' | '(' | ')' | '*' | '+' | ',' |       yes
                      '-' | '.' | '/' | '0' | '1' | '2' | '3' | '4' |
                      '5' | '6' | '7' | '8' | '9' | ':' | '<' | '=' |
                      '>' | '?' | '@' | 'A' | 'B' | 'C' | 'D' | 'E' |
                      'F' | 'G' | 'H' | 'I' | 'J' | 'K' | 'L' | 'M' |
                      'N' | 'O' | 'P' | 'Q' | 'R' | 'S' | 'T' | 'U' |
                      'V' | 'W' | 'X' | 'Y' | 'Z' | '\' | '^' | '`' |
                      'a' | 'b' | 'c' | 'd' | 'e' | 'f' | 'g' | 'h' |
                      'i' | 'j' | 'k' | 'l' | 'm' | 'n' | 'o' | 'p' |
                      'q' | 'r' | 's' | 't' | 'u' | 'v' | 'w' | 'x' |
                      'y' | 'z' | '{' | '|' | '}' | '~' }
<NonBlankChar>      <OrdinaryChar> | <double_quote> | '#' | '$' |           yes
                      <single_quote> | '_' |';' | '[' | ']'
<TextLeadChar>      <OrdinaryChar> | <double_quote> | '#' | '$' |           yes
                      <single_quote> | '_' | <SP> | <HT> |'[' | ']'
<AnyPrintChar>      <OrdinaryChar> | <double_quote> | '#' | '$' |           yes
                      <single_quote> | '_' | <SP> | <HT> | ';' | '[' | ']'

================================================================================




(ii) Machine-parsable form
================================================================================

<CIF>               ::= <Comments>? <WhiteSpace>? { <DataBlock> {
                        <WhiteSpace> <DataBlock> }* { <WhiteSpace> }? }?
<DataBlock>         ::= <DataBlockHeading> {<WhiteSpace> {
                        <DataItems> | <SaveFrame>} }*
<DataBlockHeading>  ::= <DATA_> { <NonBlankChar> }+
<SaveFrame>         ::= <SaveFrameHeading> { <WhiteSpace> <DataItems> }+
                        <WhiteSpace> <SAVE_>
<SaveFrameHeading>  ::= <SAVE_> { <NonBlankChar> }+
<DataItems>         ::= <Tag> <WhiteSpace> <Value> | <LoopHeader> <LoopBody>
<LoopHeader>        ::= <LOOP_> {<WhiteSpace> <Tag>}+
<LoopBody>          ::= <Value> { <WhiteSpace> <Value> }*

<DATA_>             ::= {'D' | 'd'} {'A' | 'a'} {'T' | 't'} {'A' | 'a'} '_'
<LOOP_>             ::= {'L' | 'l'} {'O' | 'o'} {'O' | 'o'} {'P' | 'p'} '_'
<GLOBAL_>           ::= {'G' | 'g'} {'L' | 'l'} {'O' | 'o'} {'B' | 'b'}
                        {'A' | 'a'} {'L' | 'l'} '_'
<SAVE_>             ::= {'S' | 's'} {'A' | 'a'} {'V' | 'v'} {'E' | 'e'} '_'
<STOP_>             ::= {'S' | 's'} {'T' | 't'} {'O' | 'o'} {'P' | 'p'} '_'

<Tag>               ::= '_'{ <NonBlankChar>}+
<Value>             ::= { '.' | '?' | <Numeric> | <CharString> |  <TextField> }

<Numeric>           ::= { <Number> | <Number> '(' <UnsignedInteger> ')' }
<Number>            ::= {<Integer> | <Float> }
<Integer>           ::= { '+' | '-' }? <UnsignedInteger>
<Float>             ::= { <Integer><Exponent> |
                        { {'+'|'-'} ? { {<Digit>} * '.' <UnsignedInteger> } |
                        { <Digit>} + '.' } } {<Exponent>} ? } }
<Exponent>          ::= { {'e' | 'E' } | {'e' | 'E' } { '+' | '- ' } }
                        <UnsignedInteger>
<UnsignedInteger>   ::= { <Digit> }+
<Digit>             ::= { '0' | '1' | '2' | '3' | '4' | '5' | '6' | '7' |
                          '8' | '9' }

<CharString>                      ::= <UnquotedString> | <SingleQuotedString> |
                                      <DoubleQuotedString>
<eol><UnquotedString>             ::= <eol><OrdinaryChar> {<NonBlankChar>}*
<noteol><UnquotedString>          ::= <noteol>{<OrdinaryChar>|';'}
                                      {<NonBlankChar>}*
<SingleQuotedString><WhiteSpace>  ::= <single_quote>{<AnyPrintChar>}*
                                      <single_quote> <WhiteSpace>
<DoubleQuotedString><WhiteSpace>  ::= <double_quote> {<AnyPrintChar>}*
                                      <double_quote> <WhiteSpace>
<TextField>                       ::= { <SemiColonTextField> }
<eol><SemiColonTextField>         ::= <eol>';' { {<AnyPrintChar>}* <eol>
                                      {{<TextLeadChar> {<AnyPrintChar>}*}?
                                      <eol>}* } ';'

<WhiteSpace>        ::= { <SP> | <HT> | <eol> | <TokenizedComments>}+
<Comments>          ::= { '#' {<AnyPrintChar>}* <eol>}+
<TokenizedComments> ::= { <SP> | <HT> | <eol> |}+ <Comments>

<OrdinaryChar>      ::= { '!' | '%' | '&' | '(' | ')' | '*' | '+' | ',' |
                          '-' | '.' | '/' | '0' | '1' | '2' | '3' | '4' |
                          '5' | '6' | '7' | '8' | '9' | ':' | '<' | '=' |
                          '>' | '?' | '@' | 'A' | 'B' | 'C' | 'D' | 'E' |
                          'F' | 'G' | 'H' | 'I' | 'J' | 'K' | 'L' | 'M' |
                          'N' | 'O' | 'P' | 'Q' | 'R' | 'S' | 'T' | 'U' |
                          'V' | 'W' | 'X' | 'Y' | 'Z' | '\' | '^' | '`' |
                          'a' | 'b' | 'c' | 'd' | 'e' | 'f' | 'g' | 'h' |
                          'i' | 'j' | 'k' | 'l' | 'm' | 'n' | 'o' | 'p' |
                          'q' | 'r' | 's' | 't' | 'u' | 'v' | 'w' | 'x' |
                          'y' | 'z' | '{' | '|' | '}' | '~' }
<NonBlankChar>      ::= <OrdinaryChar> | <double_quote> | '#' | '$' |
                        <single_quote> | '_' |';' | '[' | ']'
<TextLeadChar>      ::= <OrdinaryChar> | <double_quote> | '#' | '$' |
                        <single_quote> | '_' | <SP> | <HT> |'[' | ']'
<AnyPrintChar>      ::= <OrdinaryChar> | <double_quote> | '#' | '$' |
                        <single_quote> | '_' | <SP> | <HT> | ';' | '[' | ']'

================================================================================